(Difference between revisions)

Revision as of 18:06, 25 October 2007

-----------------------------------------------------
--  Append Reminders
-----------------------------------------------------
--  Created by Graham English
--  http://integral.grahamenglish.net
--  http://consulting.grahamenglish.net
--  http://www.grahamenglish.net/blog
-----------------------------------------------------
--  Released under the Creative Commons Attribution, ShareAlike license. 
-----------------------------------------------------
--  Place in ~/Library/Application Support/Quicksilver/Actions/
-----------------------------------------------------
-- USAGE
-- 1. Activate Quicksilver
-- 2. Hit '.' to activate the text area
-- 3. Type the text
-- 4. Hit the tab key to and type the name of the script (or as much of it as you need)
-- 5. Hit Enter
-----------------------------------------------------

using terms from application "Quicksilver"
	on process text theText
		set theInbox to "/Users/grahamenglish/.reminders" -- CHANGE TO YOUR PATH
		do shell script "echo " & quoted form of theText & " >> " & quoted form of theInbox
		my growlRegister()
		growlNotify("Reminders Appended", theText)
	end process text
end using terms from

using terms from application "GrowlHelperApp"
	-- Register Growl
	on growlRegister()
		tell application "GrowlHelperApp"
			register as application "Remind" all notifications {"Alert"} default notifications {"Alert"} icon of application "iCal.app"
		end tell
	end growlRegister
	
	-- Notify using Growl
	on growlNotify(grrTitle, grrDescription)
		tell application "GrowlHelperApp"
			notify with name "Alert" title grrTitle description grrDescription application name "Remind"
		end tell
	end growlNotify
end using terms from