(Difference between revisions)

Current revision as of 17:51, 30 March 2010

iQuickTwitter

How to install:

• Download the script, unzip, and put it here:

~/Library/Application Support/Quicksilver/Actions

• Using Script Editor, modify these lines of the script to your Twitter username and password:

set twitter_key_account to "[email protected]" set twitter_key_pass to "your_password"

• Restart Quicksilver.

How to use:

• Invoke Quicksilver.
• Enter text mode (hit period) and type your message.
• Tab to the Action Pane and type “Tweet” (or as much of the word as you need).
• Enter.

using terms from application "Quicksilver.app"
	on «event DAEDopnt» tweet
		set wordcount to do shell script "echo " & quoted form of tweet & " | wc -c"
		set wordcount to do shell script "echo " & quoted form of wordcount & " | sed 's/^[ 	]*//'"
		if wordcount as integer > 140 then
			my growlRegister()
			growlNotify("Tweet too long", "(" & wordcount & ") characters")
			return nothing
		end if
		set twitter_key_account to "[email protected]"
		set twitter_key_pass to "your_password"
		set twitter_login to quoted form of (twitter_key_account & ":" & twitter_key_pass)
		set twitter_status to quoted form of ("source=iQuickTwitter&status=" & tweet)
		set results to do shell script "curl --user " & twitter_login & " --data-binary " & twitter_status & " http://twitter.com/statuses/update.json"
		-- display dialog results
		my growlRegister()
		
		growlNotify("Tweet Sent", tweet)
		
		-- Uncomment (remove "--") if you want to integrate Skype mood text updates
		--		tell application "System Events"
		--			if exists process "Skype" then
		--				set commandText to "SET PROFILE MOOD_TEXT " & tweet
		--				tell application "Skype"
		--					send command commandText script name "Tweet"
		--				end tell
		--			end if
		--		end tell
		
		tell application "System Events"
			if exists process "iChat" then
				tell application "iChat"
					set the status message to tweet
				end tell
			end if
		end tell
		
	end «event DAEDopnt»
end using terms from

using terms from application "GrowlHelperApp"
	-- Register Growl
	on growlRegister()
		tell application "GrowlHelperApp"
			register as application "Tweet" all notifications {"Alert"} default notifications {"Alert"} icon of application "Twitterrific.app"
		end tell
	end growlRegister
	
	-- Notify using Growl
	-- Example: growlNotify("This is an Alert","This is a test of the Growl Alert System")
	on growlNotify(grrTitle, grrDescription)
		tell application "GrowlHelperApp"
			notify with name "Alert" title grrTitle description grrDescription application name "Tweet"
		end tell
	end growlNotify
end using terms from