(Difference between revisions)

Current revision as of 01:55, 17 March 2010

-----------------------------------------------------
--  Append GTD Inbox
-----------------------------------------------------
--  Created by Graham English
--  http://www.grahamenglish.net/
-----------------------------------------------------
--  Released under the Creative Commons Attribution, ShareAlike license. 
-----------------------------------------------------
--  Place in ~/Library/Application Support/Quicksilver/Actions/
-----------------------------------------------------
-- USAGE
-- 1. Activate Quicksilver
-- 2. Hit '.' to activate the text area
-- 3. Type the text
-- 4. Hit the tab key to and type the name of the script (or as much of it as you need)
-- 5. Hit Enter
-----------------------------------------------------

using terms from application "Quicksilver"
	on process text theText
		set theInbox to "/Users/grahamenglish/Desktop/GTD/inbox.txt" -- CHANGE TO YOUR PATH
		do shell script "echo " & quoted form of theText & " >> " & quoted form of theInbox
		my growlRegister()
		growlNotify("Inbox Appended", theText)
	end process text
end using terms from

using terms from application "GrowlHelperApp"
	-- Register Growl
	on growlRegister()
		tell application "GrowlHelperApp"
			register as application "GTDAlt" all notifications {"Alert"} default notifications {"Alert"} icon of application "TextMate.app"
		end tell
	end growlRegister
	
	-- Notify using Growl
	on growlNotify(grrTitle, grrDescription)
		tell application "GrowlHelperApp"
			notify with name "Alert" title grrTitle description grrDescription application name "GTDAlt"
		end tell
	end growlNotify
end using terms from